Plane Wave Visualization

David McIntyre
5 January 2017

Initialization

SetOptions[Plot3D,BaseStyle->{FontFamily->"Arial",FontSize->12}];

SetOptions[ParametricPlot3D,BaseStyle->{FontFamily->"Arial",FontSize->12}];

Plane wave

A given EM wave is

(OverVector[E])=(Subscript[(OverVector[E]), 0])Exp{i[-((Sqrt[3])/(2(Sqrt[2])))(Subscript[k, 0])x+((Sqrt[3])/(2(Sqrt[2])))(Subscript[k, 0])y+(1/2)(Subscript[k, 0])z-ωt]}

Identify k unit vector, knowing that any EM wave has the basic form

(OverVector[E])=(Subscript[(OverVector[E]), 0])Exp{i[(OverVector[k])·(OverVector[r])-ωt]}

k={-Sqrt[3/2]/2,Sqrt[3/2]/2,1/2}

Define r vector

r={x,y,z}

Define equation of plane with zero phase

planeequation=k.r==0

solve for equation of plane with zero phase

plane1=Solve[planeequation,z]

Plot zero phase plane

Plot3D[z/.plane1,{x,-1,1},{y,-1,1},AxesLabel->{"x","y","z"},PlotRange->{-1,1},ClippingStyle->None,BoxRatios->Automatic]

Find multiple planes at multiple phases modulo 2π

planes=Table[Solve[k.r==i*2*π,z],{i,0,10}]

pp1=Plot3D[z/.planes,{x,-30,0},{y,0,30},AxesLabel->{"x","y","z"},PlotRange->{0,30},ClippingStyle->None,ColorFunction->Function[{x,y,z},RGBColor[1,0,0]],Mesh->None,BoxRatios->Automatic]

Draw the k vector as a line and show that it isperpendicualr to the planes of constant phase

pp2=ParametricPlot3D[k*t,{t,0,50},AxesLabel->{"x","y","z"},PlotStyle->{Blue,AbsoluteThickness[4]}]

Show[pp1,pp2]

Find the spherical angles of the k vector using the Cartesian components

θ=ArcCos[k[[3]]]

ϕ=ArcTan[k[[1]],k[[2]]]

Make plots with Graphics primitives

plane1=Polygon[{{-5,-5,0},{5,-5,0},{5,5,0},{-5,5,0}}];

plane6=Table[Polygon[{{-5,-5,i},{5,-5,i},{5,5,i},{-5,5,i}}],{i,0,5}];

pol0=Table[Line[{{0,0,0},{5*Cos[i*π/10],5*Sin[i*π/10],0}}],{i,20}];

pol6=Table[Line[{{0,0,5},{5*Cos[i*π/10],5*Sin[i*π/10],5}}],{i,20}];

kvector={Blue,AbsoluteThickness[4],Line[{{0,0,0},{0,0,6}}]};

Make 6 parallel planes, 3 axes (black), k vector (blue), possible polarization directions (thin lines in top plane)
Rotate objects around  +y  by angle θ and around  +z  by angle ϕ

Graphics3D[{Rotate[Rotate[{{Opacity[0.5],plane6},kvector,pol6},θ,{0,1,0}],ϕ,{0,0,1}],
(* Axes *)  AbsoluteThickness[4],Line[{{0,0,0},{8,0,0}}],Line[{{0,0,0},{0,8,0}}],Line[{{0,0,0},{0,0,8}}]},
ImageSize->800,Boxed->False]

Find the electric field polarization direction if we assume that it lies in the yz - plane and then plot.

Solve[k.{0,Ey,Ez}==0,Ez]

pol={0,1,-Sqrt[3/2]}

Graphics3D[{Rotate[Rotate[{plane1,kvector,pol0},θ,{0,1,0}],ϕ,{0,0,1}],
(* BLACK Axes *)  AbsoluteThickness[4],Line[{{0,0,0},{6,0,0}}],Line[{{0,0,0},{0,6,0}}],Line[{{0,0,0},{0,0,6}}],
(* yz plane *)  Opacity[0.5],Polygon[{{0,-5,-5},{0,-5,5},{0,5,5},{0,5,-5}}],
(* RED polarization direction *)  Red,AbsoluteThickness[8],Line[{-4*pol,4*pol}]},ImageSize->800,Boxed->False]