Effective Potential
By Corinne Manogue
Copyright 2010 Corinne Manogue

In this worksheet you will look at the effective potential for a number of different values of various parameters.

μ is the reduced mass
U(r)=((-k)/r)  is the potential energy
ℓ is the magnitude of the angular momentum
E is the total energy:

The four plotted curves are:
1) The potential energy U(r)=((-K)/r)(blue),
2) the angular part of the kinetic energy (centrifugal barrier) ((ℓ^2)/(2((μr)^2)))(red),
3) the effective potential (Subscript[V, eff])(r)=((-k)/r)+((ℓ^2)/(2((μr)^2)))(black), i.e. the sum,
4) the total energy E (green).

SetOptions[Plot,PlotRange->{{0,5},{-1,1}},PlotStyle->{{Blue,Thick},{Red,Thick},{Black,AbsoluteThickness[4]},{Green,Thick}},AxesLabel->{"r","Energy"},ImageSize->800,BaseStyle->{FontFamily->"Arial",FontSize->16},AxesStyle->Directive[FontFamily->"Arial",FontSize->16,Black,AbsoluteThickness[0.5],Arrowheads[0.04]],TicksStyle->{{Black,AbsoluteThickness[0.5]},{Black,AbsoluteThickness[0.5]}}];

U[r_,k_]:=-k/r
CB[r_,el_,mu_]:=el^2/(2*mu*r^2)
Veff[r_,k_,el_,mu_]:=U[r,k]+CB[r,el,mu]

Manipulate[Plot[{U[r,k],CB[r,el,mu],Veff[r,k,el,mu],e},{r,0,5},PlotLabel->
"ℓ = "<>ToString[el]<>", k = "<>ToString[k]<>", μ = "<>ToString[mu]<>", E = "<>ToString[e]],{{el,1,"ℓ"},0.5,5},{k,1,4},{{mu,1,"μ"},1,10},{{e,-0.3,"E"},-5,5},LabelStyle->Large]